ESP8266 WiFi : Advance - Control LED using Webserver V1

Description
This sketch demonstrates how to set up a simple HTTP-like server to control LED light. The server will set a GPIO/Digital pin depending on the request. The IP address of the ESP8266 module, will be printed to Serial when the module is connected. You can learn basic HTML at w3school to modified HTML coding.

List Item

1. Wemos/Robotdyn D1 R2 ESP8266
2. LED
3. Resistor 220 ohm
4. Wire Jumper

Wiring Diagram

Video

Coding

/*********
  Rui Santos Owner
  Complete project details at http://randomnerdtutorials.com

  Modified by Hardy
  Visit https://microcontrollermalaysia.blogspot.com/2018/11/esp8266-wireless-control.html
  11/17/2018
*********/

// Load Wi-Fi library
#include <ESP8266WiFi.h>

// Replace with your network credentials
const char* ssid     = "controller";
const char* password = "0123456789";

// Set web server port number to 80
WiFiServer server(80);

// Variable to store the HTTP request
String header;

// Auxiliar variables to store the current output state
String LEDState1 = "off";
String LEDState2 = "off";
String LEDState3 = "off";




// Assign output variables to GPIO pins
const int LED1 = D0;
const int LED2 = D1;
const int LED3 = D2;

void setup() {
  Serial.begin(115200);
  // Initialize the output variables as outputs
  pinMode(LED1, OUTPUT);
  pinMode(LED2, OUTPUT);
  pinMode(LED3, OUTPUT);
  // Set outputs to LOW
  digitalWrite(LED1, LOW);
  digitalWrite(LED2, LOW);
  digitalWrite(LED3, LOW);


  // Connect to Wi-Fi network with SSID and password
  Serial.print("Connecting to ");
  Serial.println(ssid);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  // Print local IP address and start web server
  Serial.println("");
  Serial.println("WiFi connected.");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
  server.begin();
}

void loop(){
  WiFiClient client = server.available();   // Listen for incoming clients

  if (client) {                             // If a new client connects,
    Serial.println("New Client.");          // print a message out in the serial port
    String currentLine = "";                // make a String to hold incoming data from the client
    while (client.connected())              // loop while the client's connected
    {         
      if (client.available())               // if there's bytes to read from the client,
      {     
        char c = client.read();             // read a byte, then
        Serial.write(c);                    // print it out the serial monitor
        header += c;
        if (c == '\n')
     
        {                    // if the byte is a newline character
          // if the current line is blank, you got two newline characters in a row.
          // that's the end of the client HTTP request, so send a response:
          if (currentLine.length() == 0)
          {
            // HTTP headers always start with a response code (e.g. HTTP/1.1 200 OK)
            // and a content-type so the client knows what's coming, then a blank line:
            client.println("HTTP/1.1 200 OK");
            client.println("Content-type:text/html");
            client.println("Connection: close");
            client.println();
         
            // turns the GPIOs on and off
            if (header.indexOf("GET /1/on") >= 0)
            {
              Serial.println("LED 1 is ON");
              LEDState1 = "on";
              digitalWrite(LED1, HIGH);
            }
         
            else if (header.indexOf("GET /1/off") >= 0)
            {
              Serial.println("LED 1 is OFF");
              LEDState1 = "off";
              digitalWrite(LED1, LOW);
            }
         
            else if (header.indexOf("GET /2/on") >= 0)
            {
              Serial.println("LED 2 is ON");
              LEDState2 = "on";
              digitalWrite(LED2, HIGH);
            }
         
            else if (header.indexOf("GET /2/off") >= 0)
            {
              Serial.println("LED 2 is OFF");
              LEDState2 = "off";
              digitalWrite(LED2, LOW);
            }

            else if (header.indexOf("GET /3/on") >= 0)
            {
              Serial.println("LED 3 is ON");
              LEDState3 = "on";
              digitalWrite(LED3, HIGH);
            }
         
            else if (header.indexOf("GET /3/off") >= 0)
            {
              Serial.println("LED 1 is OFF");
              LEDState3 = "off";
              digitalWrite(LED3, LOW);
            }
         
            // Display the HTML web page
            client.println("<!DOCTYPE html><html>");
            client.println("<head><meta name=\"viewport\" content=\"width=device-width, initial-scale=1\">");
            client.println("<link rel=\"icon\" href=\"data:,\">");
            // CSS to style the on/off buttons
            // Feel free to change the background-color and font-size attributes to fit your preferences
            client.println("<style>html { font-family: Helvetica; display: inline-block; margin: 0px auto; text-align: center;}");
            client.println(".button { background-color: #195B6A; border: none; color: white; padding: 16px 40px;");
            client.println("text-decoration: none; font-size: 30px; margin: 2px; cursor: pointer;}");
            client.println(".button2 {background-color: #77878A;}</style></head>");
         
            // Web Page Heading
            client.println("<body bgcolor=\"#00BFFF8\"><h1>ESP8266 Web Server LED Control</h1>"); //you can change background colour at bgcolor using HEX code
            client.println("<p><a href=\"https://microcontrollermalaysia.blogspot.com\"><img alt=\"\" src=\"http://techaisle.com/images/headers/IoT_header_1920x400.jpg\" style=\"width:640px; height:128px;\"></a></p>"); // Change image URL

            // Display current state, and ON/OFF buttons for Digital Pin D0
            client.println("<p>LED 1 - " + LEDState1 + "</p>"); // If the LED 1 State is off, it displays the ON button     
            if (LEDState1=="off")
            {
              client.println("<p><a href=\"/1/on\"><button class=\"button\">ON</button></a></p>");
            } else
            {
              client.println("<p><a href=\"/1/off\"><button class=\"button button2\">OFF</button></a></p>");
            }
             
            // Display current state, and ON/OFF buttons for Digital Pin D1
            client.println("<p>LED 2 - " + LEDState2 + "</p>"); // If the LED 2 State is off, it displays the ON button 
            if (LEDState2=="off")
            {
              client.println("<p><a href=\"/2/on\"><button class=\"button\">ON</button></a></p>");
            }
         
            else
            {
              client.println("<p><a href=\"/2/off\"><button class=\"button button2\">OFF</button></a></p>");
            }

            // Display current state, and ON/OFF buttons for Digital Pin D2
            client.println("<p>LED 3 - " + LEDState3 + "</p>"); // If the LED 3 State is off, it displays the ON button 
            if (LEDState3=="off")
            {
              client.println("<p><a href=\"/3/on\"><button class=\"button\">ON</button></a></p>");
            }
         
            else
            {
              client.println("<p><a href=\"/3/off\"><button class=\"button button2\">OFF</button></a></p>");
            }

         
            client.println("</body></html>");
         
            // The HTTP response ends with another blank line
            client.println();
            // Break out of the while loop
            break;
            }
       
          else
          { // if you got a newline, then clear currentLine
            currentLine = "";
          }
        }
        else if (c != '\r') {  // if you got anything else but a carriage return character,
          currentLine += c;      // add it to the end of the currentLine
        }
      }
    }
    // Clear the header variable
    header = "";
    // Close the connection
    client.stop();
    Serial.println("Client disconnected.");
    Serial.println("");
  }
}